Puppet Class: sensu
- Defined in:
- manifests/init.pp
Summary
Base Sensu classOverview
This is the main Sensu class
349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485 486 487 488 489 490 491 492 493 494 495 496 497 498 499 500 501 502 503 504 505 506 507 508 509 510 511 512 513 514 515 516 517 518 519 520 521 522 523 524 525 526 527 528 529 530 531 532 533 534 535 536 537 538 539 540 541 542 543 544 545 546 547 548 549 550 551 552 553 554 555 556 557 558 559 560 561 562 563 564 565 566 567 568 569 570 571 572 573 574 575 576 577 578 579 580 581 582 583 584 585 586 587 588 589 590 591 592 593 594 595 596 597 598 599 600 601 602 603 604 605 606 607 608 609 610 611 612 613 614 615 616 617 618 619 620 621 622 623 624 625 626 627 628 629 630 631 632 633 634 635 636 637 638 639 640 641 642 643 644 645 646 647 648 649 650 651 652 653 654 655 656 657 658 659 660 661 662 663 664 665 666 667 668 669 670 671 672 673 674 675 676 677 678 679 680 681 682 683 684 685 686 687 688 689 690 691 692 693 694 695 696 697 698 699 700 701 702 703 704 705 706 707 708 709 710 711 712 |
# File 'manifests/init.pp', line 349
class sensu (
Pattern[/^absent$/, /^installed$/, /^latest$/, /^present$/, /^[\d\.\-el]+$/] $version = 'installed',
String $sensu_plugin_name = 'sensu-plugin',
Optional[String] $sensu_plugin_provider = $::osfamily ? {
'windows' => 'gem',
default => undef,
},
Stdlib::Absolutepath $sensu_etc_dir = $::osfamily ? {
'windows' => 'C:/opt/sensu',
default => '/etc/sensu',
},
Pattern[/^absent$/, /^installed$/, /^latest$/, /^present$/, /^\d[\d\.\-\w]+$/] $sensu_plugin_version = 'installed',
Boolean $install_repo = true,
Boolean $enterprise = false,
Pattern[/^absent$/,/^installed$/,/^latest$/,/^present$/,/^[\d\.\-]+$/] $enterprise_version = 'latest',
Optional[String] $enterprise_user = undef,
Optional[String] $enterprise_pass = undef,
Boolean $enterprise_dashboard = false,
String $enterprise_dashboard_version = 'latest',
Boolean $manage_repo = true,
Enum['main','unstable'] $repo = 'main',
Optional[String] $repo_source = undef,
String $repo_key_id = 'EE15CFF6AB6E4E290FDAB681A20F259AEB9C94BB',
String $repo_key_source = 'https://sensu.global.ssl.fastly.net/apt/pubkey.gpg',
Optional[String] $repo_release = undef,
Variant[Undef,Integer,Pattern[/^(\d+)$/]] $spawn_limit = undef,
String $enterprise_repo_key_id = '910442FF8781AFD0995D14B311AB27E8C3FE3269',
Boolean $client = true,
Boolean $server = false,
Boolean $api = false,
Boolean $manage_services = true,
Boolean $client_service_enable = true,
String $client_service_ensure = running,
Boolean $server_service_enable = true,
String $server_service_ensure = running,
Boolean $manage_user = true,
Boolean $manage_plugins_dir = true,
Boolean $manage_handlers_dir = true,
Boolean $manage_mutators_dir = true,
Optional[String] $sensu_user = undef,
Optional[String] $sensu_group = undef,
Optional[Stdlib::Filemode] $config_dir_mode = $::osfamily ? {
'windows' => undef,
default => '0555',
},
Optional[Stdlib::Filemode] $config_file_mode = $::osfamily ? {
'windows' => undef,
default => '0440',
},
Variant[Undef,Integer,Pattern[/^(\d+)$/]] $rabbitmq_port = undef,
Optional[String] $rabbitmq_host = undef,
Optional[String] $rabbitmq_user = undef,
Optional[String] $rabbitmq_password = undef,
Optional[String] $rabbitmq_vhost = undef,
Optional[Boolean] $rabbitmq_ssl = undef,
Optional[String] $rabbitmq_ssl_private_key = undef,
Optional[String] $rabbitmq_ssl_cert_chain = undef,
Variant[Undef,Integer,Pattern[/^(\d+)$/]] $rabbitmq_prefetch = undef,
Variant[Undef,Hash,Array] $rabbitmq_cluster = undef,
Variant[Undef,Integer,Pattern[/^(\d+)$/]] $rabbitmq_heartbeat = undef,
Optional[String] $redis_host = '127.0.0.1',
Variant[Undef,Integer,Pattern[/^(\d+)$/]] $redis_port = 6379,
Optional[String] $redis_password = undef,
Boolean $redis_reconnect_on_error = true,
Integer $redis_db = 0,
Boolean $redis_auto_reconnect = true,
Boolean $redis_tls = false,
Optional[Array] $redis_sentinels = undef,
Optional[String] $redis_master = undef,
Enum['rabbitmq','redis'] $transport_type = 'rabbitmq',
Boolean $transport_reconnect_on_error = true,
String $api_bind = '0.0.0.0',
String $api_host = '127.0.0.1',
Integer $api_port = 4567,
Optional[String] $api_user = undef,
Optional[String] $api_password = undef,
Variant[Undef,Integer,Pattern[/^(\d+)$/]] $api_ssl_port = undef,
Optional[String] $api_ssl_keystore_file = undef,
Optional[String] $api_ssl_keystore_password = undef,
Variant[String,Array] $subscriptions = [],
Boolean $client_socket_enabled = true,
String $client_bind = '127.0.0.1',
Integer $client_port = 3030,
String $client_address = $::ipaddress,
String $client_name = $::fqdn,
Hash $client_custom = {},
Variant[Undef,Boolean] $client_deregister = undef,
Variant[Undef,Hash] $client_deregistration = undef,
Variant[Undef,Hash] $client_registration = undef,
Hash $client_keepalive = {},
Hash $client_http_socket = {},
Hash $client_servicenow = {},
Hash $client_ec2 = {},
Hash $client_chef = {},
Hash $client_puppet = {},
Boolean $safe_mode = false,
Variant[String,Array,Hash] $plugins = [],
Hash $plugins_defaults = {},
Optional[String] $plugins_dir = undef,
Variant[Boolean,Hash] $purge = false,
Boolean $purge_config = false,
Boolean $purge_plugins_dir = false,
Boolean $use_embedded_ruby = true,
Optional[String] $rubyopt = undef,
Optional[String] $gem_path = undef,
Enum['debug','info','warn','error','fatal'] $log_level = 'info',
Stdlib::Absolutepath $log_dir = '/var/log/sensu',
Boolean $dashboard = false,
Variant[Integer,Pattern[/^(\d+)$/]] $init_stop_max_wait = 10,
Optional[Any] $gem_install_options = undef,
Boolean $hasrestart = true,
Optional[String] $enterprise_dashboard_base_path = undef,
Optional[String] $enterprise_dashboard_host = undef,
Variant[Undef,Integer,Pattern[/^(\d+)$/]] $enterprise_dashboard_port = undef,
Optional[Any] $enterprise_dashboard_refresh = undef,
Optional[String] $enterprise_dashboard_user = undef,
Optional[String] $enterprise_dashboard_pass = undef,
Optional[Any] $enterprise_dashboard_auth = undef,
Optional[Any] $enterprise_dashboard_ssl = undef,
Optional[Any] $enterprise_dashboard_audit = undef,
Optional[Any] $enterprise_dashboard_github = undef,
Optional[Any] $enterprise_dashboard_gitlab = undef,
Optional[Any] $enterprise_dashboard_ldap = undef,
Optional[Any] $enterprise_dashboard_oidc = undef,
Optional[Hash] $enterprise_dashboard_custom = undef,
Variant[Stdlib::Absolutepath,Pattern[/^\$PATH$/]] $path = '$PATH',
Optional[Hash[String[1], Variant[String, Boolean, Integer]]] $env_vars = {},
Optional[Array] $redact = undef,
Boolean $deregister_on_stop = false,
Optional[String] $deregister_handler = undef,
Optional[String] $package_checksum = undef,
Optional[String] $windows_pkg_url = undef,
Optional[String] $windows_repo_prefix = 'https://repositories.sensuapp.org/msi',
Boolean $windows_logrotate = false,
Variant[Integer,Pattern[/^(\d+)$/]] $windows_log_number = 10,
Variant[Integer,Pattern[/^(\d+)$/]] $windows_log_size = 10240,
Optional[String] $windows_package_provider = undef,
Optional[String] $windows_choco_repo = undef,
String $windows_package_name = 'Sensu',
String $windows_package_title = 'sensu',
Optional[Struct[{NotUndef[user] => String, NotUndef[password] => String}]] $windows_service_user = undef,
Optional[Variant[Stdlib::Absolutepath,Array[Stdlib::Absolutepath]]] $confd_dir = undef,
Variant[Integer,Pattern[/^(\d+)/],Undef] $heap_size = undef,
Variant[Stdlib::Absolutepath,Undef] $config_file = undef,
Variant[Undef,Integer,Pattern[/^(\d+)$/]] $max_open_files = undef,
Variant[Undef,String] $heap_dump_path = undef,
Variant[Undef,String] $java_opts = undef,
### START Hiera Lookups###
Hash $extensions = {},
Hash $handlers = {},
Hash $handler_defaults = {},
Hash $checks = {},
Hash $check_defaults = {},
Hash $filters = {},
Hash $filter_defaults = {},
Hash $mutators = {},
### END Hiera Lookups ###
) {
case $::kernel {
'Darwin': {
$api_service_name = 'org.sensuapp.sensu-api'
$etc_dir = $sensu_etc_dir
$conf_dir = "${etc_dir}/conf.d"
$user = '_sensu'
$group = 'wheel'
$home_dir = '/opt/sensu'
$shell = '/bin/false'
$dir_mode = $config_dir_mode
$file_mode = $config_file_mode
$service_name = 'org.sensuapp.sensu-client'
}
'Linux': {
$api_service_name = 'sensu-api'
$etc_dir = $sensu_etc_dir
$conf_dir = "${etc_dir}/conf.d"
$user = $sensu_user ? {
undef => 'sensu',
default => $sensu_user,
}
$group = $sensu_group ? {
undef => 'sensu',
default => $sensu_group,
}
$home_dir = '/opt/sensu'
$shell = '/bin/false'
$dir_mode = $config_dir_mode
$file_mode = $config_file_mode
$service_name = 'sensu-client'
}
'windows': {
$api_service_name = undef
$etc_dir = $sensu_etc_dir
$conf_dir = "${etc_dir}/conf.d"
$user = $sensu_user ? {
undef => 'NT Authority\SYSTEM',
default => $sensu_user,
}
$group = $sensu_group ? {
undef => 'Administrators',
default => $sensu_group,
}
$home_dir = $etc_dir
$shell = undef
$dir_mode = $config_dir_mode
$file_mode = $config_file_mode
$service_name = 'sensu-client'
}
default: {
fail("Detected kernel is <${::kernel}> and must be Darwin, Linux or windows.")
}
}
if $dashboard { fail('Sensu-dashboard is deprecated, use a dashboard module. See https://github.com/sensu/sensu-puppet#dashboards')}
if $purge_config { fail('purge_config is deprecated, set the purge parameter to a hash containing `config => true` instead') }
if $purge_plugins_dir { fail('purge_plugins_dir is deprecated, set the purge parameter to a hash containing `plugins => true` instead') }
# sensu-enterprise supersedes sensu-server and sensu-api
if ( $enterprise and $api ) or ( $enterprise and $server ) {
fail('Sensu Enterprise: sensu-enterprise replaces sensu-server and sensu-api')
}
# validate enterprise repo credentials
if $manage_repo {
if ( $enterprise or $enterprise_dashboard ) and $install_repo {
if $enterprise_user == undef or $enterprise_pass == undef {
fail('The Sensu Enterprise repos require both enterprise_user and enterprise_pass to be set')
}
}
}
# Put here to avoid computing the conditionals for every check
if $client and $manage_services {
$client_service = Service['sensu-client']
} else {
$client_service = undef
}
if $enterprise and $manage_services {
$enterprise_service = Service['sensu-enterprise']
} else {
$enterprise_service = undef
}
if $server {
$server_service_class = Class['sensu::server::service']
} else {
$server_service_class = undef
}
if $api and $manage_services and $::osfamily != 'windows' {
$api_service = $::osfamily ? {
'Darwin' => Service['org.sensuapp.sensu-client'],
default => Service[$api_service_name],
}
} else {
$api_service = undef
}
$_check_notify = [ $client_service, $server_service_class, $api_service, $enterprise_service ]
$check_notify = $_check_notify.filter |$val| { $val =~ NotUndef }
# Because you can't reassign a variable in puppet and we need to set to
# false if you specify a directory, we have to use another variable.
if $plugins_dir {
$_manage_plugins_dir = false
} else {
$_manage_plugins_dir = $manage_plugins_dir
}
if $purge =~ Boolean {
# If purge is a boolean, we either purge everything or purge nothing
$_purge_plugins = $purge
$_purge_config = $purge
$_purge_handlers = $purge
$_purge_extensions = $purge
$_purge_mutators = $purge
} else {
# Default anything not specified to false
$default_purge_hash = { plugins => false, config => false, handlers => false, extensions => false, mutators => false }
$full_purge_hash = merge($default_purge_hash, $purge)
validate_bool($full_purge_hash['plugins'], $full_purge_hash['config'], $full_purge_hash['handlers'], $full_purge_hash['extensions'], $full_purge_hash['mutators'])
# Check that all keys are valid
$invalid_keys = difference(keys($purge), keys($default_purge_hash))
if !empty($invalid_keys) {
fail("Invalid keys for purge parameter: ${invalid_keys}")
}
$_purge_plugins = $full_purge_hash['plugins']
$_purge_config = $full_purge_hash['config']
$_purge_handlers = $full_purge_hash['handlers']
$_purge_extensions = $full_purge_hash['extensions']
$_purge_mutators = $full_purge_hash['mutators']
}
# (#463) This well-known anchor serves as a reference point so all checks are
# managed after all plugins. It must always exist in the catalog.
anchor { 'plugins_before_checks': }
$extensions.each |$k,$v| {
::sensu::extension { $k:
* => $v,
}
}
$handlers.each |$k,$v| {
::sensu::handler { $k:
* => $handler_defaults + $v,
}
}
$checks.each |$k,$v| {
::sensu::check { $k:
* => $check_defaults + $v,
}
}
$filters.each |$k,$v| {
::sensu::filter { $k:
* => $filter_defaults + $v,
}
}
$mutators.each |$k,$v| {
::sensu::mutator { $k:
* => $v,
}
}
# Include everything and let each module determine its state. This allows
# transitioning to purged config and stopping/disabling services
contain ::sensu::package
contain ::sensu::enterprise
contain ::sensu::transport
contain ::sensu::rabbitmq::config
contain ::sensu::api
contain ::sensu::redis::config
contain ::sensu::client
contain ::sensu::server::service
contain ::sensu::enterprise::dashboard
Class['::sensu::package']
-> Class['::sensu::transport']
-> Class['::sensu::rabbitmq::config']
-> Sensu_api_config[$::fqdn]
-> Class['::sensu::redis::config']
-> Sensu_client_config[$::fqdn]
-> Class['::sensu::server::service']
-> Class['::sensu::enterprise::dashboard']
# Dependencies for Plugins #
# Without this line, plugins installed with the sensu_gem provider may get
# evaluated before the sensu package, which, on sensu package upgrades that
# install a new version of Ruby, would mean that two runs of Puppet would be
# necessary to get the plugins installed into the new embedded Ruby folder.
Package['sensu']
~> Package<| provider == 'sensu_gem' |>
~> Service<| title == 'sensu-client' or title == 'sensu-server' or title == 'sensu-api'|>
if $plugins_dir {
sensu::plugin { $plugins_dir: type => 'directory' }
} else {
case $plugins {
String,Array: { sensu::plugin { $plugins: } }
Hash: { create_resources('::sensu::plugin', $plugins, $plugins_defaults ) }
default: { fail('Invalid data type for $plugins, must be a string, an array, or a hash.') }
}
}
}
|